日本語のAcrionScript1.0/2.0【 3Dサンプル 】

AcrionScript1.0/2.0って変数に日本語使えるんですね。

変数や関数名を日本語ですると、コメント書かなくても流れが分かりやすそう。

とりあえず3Dシミュレーションを日本語ASで書いてみました。

どこにでもありそうな3Dシミュレーションコードです。

以下をフレームアクションに記述。_rootの1フレーム目にコピペで動きます。
Flash6以上、ライブラリに「circle」というリンケージ名のシンボル(100×100ぐらいの大きさのシェイプだけのMCがお勧め)を用意して下さい。

//_root [フレーム1] フレームアクション

var レンダリング = function ( 配列 )
{
	var n = 配列.length
	var 焦点 = 350
	while( n-- )
	{
		var mc = 配列[ n ]
		var pers = 焦点 / mc.z
		pers = pers > 0 ? pers : 0
		mc._x = mc.x * pers
		mc._y = mc.y * pers
		mc._xscale = mc._yscale = 100 * pers
		mc.swapDepths( 1000000 - Math.floor( mc.z ) )
	}
}


var 生成 = function( 配列 )
{
	var コンテナ = _root.createEmptyMovieClip( "コンテナ" , 0 )
	コンテナ._x = Stage.width / 2
	コンテナ._y = Stage.height / 2
	
	var r = 1000
	var n = 0
	
	while( n++ < 100 )
	{
		var mc = コンテナ.attachMovie( "circle" , "m" + n , n )
		mc.x = r * ( -Math.random() + .5 )
		mc.y = r * ( -Math.random() + .5 )
		mc.z = Ｚ座標中心点 + r * n
		mc.d = -100 * Math.random()
		mc.n = n
		配列.push( mc )
	}
}


var 座標更新 = function( 配列 )
{
	var n = 配列.length
	while( n-- )
	{
		var mc = 配列[ n ]
		mc.z += mc.d
		mc.z = mc.z < 0 ? 100000 : mc.z
	}
}




//メイン処理
var Ｚ座標中心点 = -80000
var シンボル = []
生成( シンボル )

onEnterFrame = function()
{
	座標更新( シンボル )
	レンダリング( シンボル )
}

パブリッシュしたら1KBでした。軽い。

関連記事

ActionScript Editor - Yasu Log::Flash/Flex/AIR::ブログ
ループ文速度比較 - Yasu Log::Flash/Flex/AIR::ブログ